home *** CD-ROM | disk | FTP | other *** search
/ Personal Computer World 2009 February / PCWFEB09.iso / Software / Linux / Kubuntu 8.10 / kubuntu-8.10-desktop-i386.iso / casper / filesystem.squashfs / usr / share / perl5 / HTTP / Response.pm < prev    next >
Text File  |  2008-04-14  |  12KB  |  454 lines
  1. package HTTP::Response;
  2.  
  3. require HTTP::Message;
  4. @ISA = qw(HTTP::Message);
  5. $VERSION = "5.811";
  6.  
  7. use strict;
  8. use HTTP::Status ();
  9.  
  10.  
  11.  
  12. sub new
  13. {
  14.     my($class, $rc, $msg, $header, $content) = @_;
  15.     my $self = $class->SUPER::new($header, $content);
  16.     $self->code($rc);
  17.     $self->message($msg);
  18.     $self;
  19. }
  20.  
  21.  
  22. sub parse
  23. {
  24.     my($class, $str) = @_;
  25.     my $status_line;
  26.     if ($str =~ s/^(.*)\n//) {
  27.     $status_line = $1;
  28.     }
  29.     else {
  30.     $status_line = $str;
  31.     $str = "";
  32.     }
  33.  
  34.     my $self = $class->SUPER::parse($str);
  35.     my($protocol, $code, $message);
  36.     if ($status_line =~ /^\d{3} /) {
  37.        # Looks like a response created by HTTP::Response->new
  38.        ($code, $message) = split(' ', $status_line, 2);
  39.     } else {
  40.        ($protocol, $code, $message) = split(' ', $status_line, 3);
  41.     }
  42.     $self->protocol($protocol) if $protocol;
  43.     $self->code($code) if defined($code);
  44.     $self->message($message) if defined($message);
  45.     $self;
  46. }
  47.  
  48.  
  49. sub clone
  50. {
  51.     my $self = shift;
  52.     my $clone = bless $self->SUPER::clone, ref($self);
  53.     $clone->code($self->code);
  54.     $clone->message($self->message);
  55.     $clone->request($self->request->clone) if $self->request;
  56.     # we don't clone previous
  57.     $clone;
  58. }
  59.  
  60.  
  61. sub code      { shift->_elem('_rc',      @_); }
  62. sub message   { shift->_elem('_msg',     @_); }
  63. sub previous  { shift->_elem('_previous',@_); }
  64. sub request   { shift->_elem('_request', @_); }
  65.  
  66.  
  67. sub status_line
  68. {
  69.     my $self = shift;
  70.     my $code = $self->{'_rc'}  || "000";
  71.     my $mess = $self->{'_msg'} || HTTP::Status::status_message($code) || "Unknown code";
  72.     return "$code $mess";
  73. }
  74.  
  75.  
  76. sub base
  77. {
  78.     my $self = shift;
  79.     my $base = $self->header('Content-Base')     ||  # used to be HTTP/1.1
  80.                $self->header('Content-Location') ||  # HTTP/1.1
  81.                $self->header('Base');                # HTTP/1.0
  82.     if ($base && $base =~ /^$URI::scheme_re:/o) {
  83.     # already absolute
  84.     return $HTTP::URI_CLASS->new($base);
  85.     }
  86.  
  87.     my $req = $self->request;
  88.     if ($req) {
  89.         # if $base is undef here, the return value is effectively
  90.         # just a copy of $self->request->uri.
  91.         return $HTTP::URI_CLASS->new_abs($base, $req->uri);
  92.     }
  93.  
  94.     # can't find an absolute base
  95.     return undef;
  96. }
  97.  
  98.  
  99. sub as_string
  100. {
  101.     require HTTP::Status;
  102.     my $self = shift;
  103.     my($eol) = @_;
  104.     $eol = "\n" unless defined $eol;
  105.  
  106.     my $status_line = $self->status_line;
  107.     my $proto = $self->protocol;
  108.     $status_line = "$proto $status_line" if $proto;
  109.  
  110.     return join($eol, $status_line, $self->SUPER::as_string(@_));
  111. }
  112.  
  113.  
  114. sub is_info     { HTTP::Status::is_info     (shift->{'_rc'}); }
  115. sub is_success  { HTTP::Status::is_success  (shift->{'_rc'}); }
  116. sub is_redirect { HTTP::Status::is_redirect (shift->{'_rc'}); }
  117. sub is_error    { HTTP::Status::is_error    (shift->{'_rc'}); }
  118.  
  119.  
  120. sub error_as_HTML
  121. {
  122.     require HTML::Entities;
  123.     my $self = shift;
  124.     my $title = 'An Error Occurred';
  125.     my $body  = HTML::Entities::encode($self->status_line);
  126.     return <<EOM;
  127. <html>
  128. <head><title>$title</title></head>
  129. <body>
  130. <h1>$title</h1>
  131. <p>$body</p>
  132. </body>
  133. </html>
  134. EOM
  135. }
  136.  
  137.  
  138. sub current_age
  139. {
  140.     my $self = shift;
  141.     # Implementation of RFC 2616 section 13.2.3
  142.     # (age calculations)
  143.     my $response_time = $self->client_date;
  144.     my $date = $self->date;
  145.  
  146.     my $age = 0;
  147.     if ($response_time && $date) {
  148.     $age = $response_time - $date;  # apparent_age
  149.     $age = 0 if $age < 0;
  150.     }
  151.  
  152.     my $age_v = $self->header('Age');
  153.     if ($age_v && $age_v > $age) {
  154.     $age = $age_v;   # corrected_received_age
  155.     }
  156.  
  157.     my $request = $self->request;
  158.     if ($request) {
  159.     my $request_time = $request->date;
  160.     if ($request_time) {
  161.         # Add response_delay to age to get 'corrected_initial_age'
  162.         $age += $response_time - $request_time;
  163.     }
  164.     }
  165.     if ($response_time) {
  166.     $age += time - $response_time;
  167.     }
  168.     return $age;
  169. }
  170.  
  171.  
  172. sub freshness_lifetime
  173. {
  174.     my $self = shift;
  175.  
  176.     # First look for the Cache-Control: max-age=n header
  177.     my @cc = $self->header('Cache-Control');
  178.     if (@cc) {
  179.     my $cc;
  180.     for $cc (@cc) {
  181.         my $cc_dir;
  182.         for $cc_dir (split(/\s*,\s*/, $cc)) {
  183.         if ($cc_dir =~ /max-age\s*=\s*(\d+)/i) {
  184.             return $1;
  185.         }
  186.         }
  187.     }
  188.     }
  189.  
  190.     # Next possibility is to look at the "Expires" header
  191.     my $date = $self->date || $self->client_date || time;      
  192.     my $expires = $self->expires;
  193.     unless ($expires) {
  194.     # Must apply heuristic expiration
  195.     my $last_modified = $self->last_modified;
  196.     if ($last_modified) {
  197.         my $h_exp = ($date - $last_modified) * 0.10;  # 10% since last-mod
  198.         if ($h_exp < 60) {
  199.         return 60;  # minimum
  200.         }
  201.         elsif ($h_exp > 24 * 3600) {
  202.         # Should give a warning if more than 24 hours according to
  203.         # RFC 2616 section 13.2.4, but I don't know how to do it
  204.         # from this function interface, so I just make this the
  205.         # maximum value.
  206.         return 24 * 3600;
  207.         }
  208.         return $h_exp;
  209.     }
  210.     else {
  211.         return 3600;  # 1 hour is fallback when all else fails
  212.     }
  213.     }
  214.     return $expires - $date;
  215. }
  216.  
  217.  
  218. sub is_fresh
  219. {
  220.     my $self = shift;
  221.     $self->freshness_lifetime > $self->current_age;
  222. }
  223.  
  224.  
  225. sub fresh_until
  226. {
  227.     my $self = shift;
  228.     return $self->freshness_lifetime - $self->current_age + time;
  229. }
  230.  
  231. 1;
  232.  
  233.  
  234. __END__
  235.  
  236. =head1 NAME
  237.  
  238. HTTP::Response - HTTP style response message
  239.  
  240. =head1 SYNOPSIS
  241.  
  242. Response objects are returned by the request() method of the C<LWP::UserAgent>:
  243.  
  244.     # ...
  245.     $response = $ua->request($request)
  246.     if ($response->is_success) {
  247.         print $response->content;
  248.     }
  249.     else {
  250.         print STDERR $response->status_line, "\n";
  251.     }
  252.  
  253. =head1 DESCRIPTION
  254.  
  255. The C<HTTP::Response> class encapsulates HTTP style responses.  A
  256. response consists of a response line, some headers, and a content
  257. body. Note that the LWP library uses HTTP style responses even for
  258. non-HTTP protocol schemes.  Instances of this class are usually
  259. created and returned by the request() method of an C<LWP::UserAgent>
  260. object.
  261.  
  262. C<HTTP::Response> is a subclass of C<HTTP::Message> and therefore
  263. inherits its methods.  The following additional methods are available:
  264.  
  265. =over 4
  266.  
  267. =item $r = HTTP::Response->new( $code )
  268.  
  269. =item $r = HTTP::Response->new( $code, $msg )
  270.  
  271. =item $r = HTTP::Response->new( $code, $msg, $header )
  272.  
  273. =item $r = HTTP::Response->new( $code, $msg, $header, $content )
  274.  
  275. Constructs a new C<HTTP::Response> object describing a response with
  276. response code $code and optional message $msg.  The optional $header
  277. argument should be a reference to an C<HTTP::Headers> object or a
  278. plain array reference of key/value pairs.  The optional $content
  279. argument should be a string of bytes.  The meaning these arguments are
  280. described below.
  281.  
  282. =item $r = HTTP::Response->parse( $str )
  283.  
  284. This constructs a new response object by parsing the given string.
  285.  
  286. =item $r->code
  287.  
  288. =item $r->code( $code )
  289.  
  290. This is used to get/set the code attribute.  The code is a 3 digit
  291. number that encode the overall outcome of a HTTP response.  The
  292. C<HTTP::Status> module provide constants that provide mnemonic names
  293. for the code attribute.
  294.  
  295. =item $r->message
  296.  
  297. =item $r->message( $message )
  298.  
  299. This is used to get/set the message attribute.  The message is a short
  300. human readable single line string that explains the response code.
  301.  
  302. =item $r->header( $field )
  303.  
  304. =item $r->header( $field => $value )
  305.  
  306. This is used to get/set header values and it is inherited from
  307. C<HTTP::Headers> via C<HTTP::Message>.  See L<HTTP::Headers> for
  308. details and other similar methods that can be used to access the
  309. headers.
  310.  
  311. =item $r->content
  312.  
  313. =item $r->content( $bytes )
  314.  
  315. This is used to get/set the raw content and it is inherited from the
  316. C<HTTP::Message> base class.  See L<HTTP::Message> for details and
  317. other methods that can be used to access the content.
  318.  
  319. =item $r->decoded_content( %options )
  320.  
  321. This will return the content after any C<Content-Encoding> and
  322. charsets have been decoded.  See L<HTTP::Message> for details.
  323.  
  324. =item $r->request
  325.  
  326. =item $r->request( $request )
  327.  
  328. This is used to get/set the request attribute.  The request attribute
  329. is a reference to the the request that caused this response.  It does
  330. not have to be the same request passed to the $ua->request() method,
  331. because there might have been redirects and authorization retries in
  332. between.
  333.  
  334. =item $r->previous
  335.  
  336. =item $r->previous( $response )
  337.  
  338. This is used to get/set the previous attribute.  The previous
  339. attribute is used to link together chains of responses.  You get
  340. chains of responses if the first response is redirect or unauthorized.
  341. The value is C<undef> if this is the first response in a chain.
  342.  
  343. =item $r->status_line
  344.  
  345. Returns the string "E<lt>code> E<lt>message>".  If the message attribute
  346. is not set then the official name of E<lt>code> (see L<HTTP::Status>)
  347. is substituted.
  348.  
  349. =item $r->base
  350.  
  351. Returns the base URI for this response.  The return value will be a
  352. reference to a URI object.
  353.  
  354. The base URI is obtained from one the following sources (in priority
  355. order):
  356.  
  357. =over 4
  358.  
  359. =item 1.
  360.  
  361. Embedded in the document content, for instance <BASE HREF="...">
  362. in HTML documents.
  363.  
  364. =item 2.
  365.  
  366. A "Content-Base:" or a "Content-Location:" header in the response.
  367.  
  368. For backwards compatibility with older HTTP implementations we will
  369. also look for the "Base:" header.
  370.  
  371. =item 3.
  372.  
  373. The URI used to request this response. This might not be the original
  374. URI that was passed to $ua->request() method, because we might have
  375. received some redirect responses first.
  376.  
  377. =back
  378.  
  379. If neither of these sources provide an absolute URI, undef is
  380. returned.
  381.  
  382. When the LWP protocol modules produce the HTTP::Response object, then
  383. any base URI embedded in the document (step 1) will already have
  384. initialized the "Content-Base:" header. This means that this method
  385. only performs the last 2 steps (the content is not always available
  386. either).
  387.  
  388. =item $r->as_string
  389.  
  390. =item $r->as_string( $eol )
  391.  
  392. Returns a textual representation of the response.
  393.  
  394. =item $r->is_info
  395.  
  396. =item $r->is_success
  397.  
  398. =item $r->is_redirect
  399.  
  400. =item $r->is_error
  401.  
  402. These methods indicate if the response was informational, successful, a
  403. redirection, or an error.  See L<HTTP::Status> for the meaning of these.
  404.  
  405. =item $r->error_as_HTML
  406.  
  407. Returns a string containing a complete HTML document indicating what
  408. error occurred.  This method should only be called when $r->is_error
  409. is TRUE.
  410.  
  411. =item $r->current_age
  412.  
  413. Calculates the "current age" of the response as specified by RFC 2616
  414. section 13.2.3.  The age of a response is the time since it was sent
  415. by the origin server.  The returned value is a number representing the
  416. age in seconds.
  417.  
  418. =item $r->freshness_lifetime
  419.  
  420. Calculates the "freshness lifetime" of the response as specified by
  421. RFC 2616 section 13.2.4.  The "freshness lifetime" is the length of
  422. time between the generation of a response and its expiration time.
  423. The returned value is a number representing the freshness lifetime in
  424. seconds.
  425.  
  426. If the response does not contain an "Expires" or a "Cache-Control"
  427. header, then this function will apply some simple heuristic based on
  428. 'Last-Modified' to determine a suitable lifetime.
  429.  
  430. =item $r->is_fresh
  431.  
  432. Returns TRUE if the response is fresh, based on the values of
  433. freshness_lifetime() and current_age().  If the response is no longer
  434. fresh, then it has to be refetched or revalidated by the origin
  435. server.
  436.  
  437. =item $r->fresh_until
  438.  
  439. Returns the time when this entity is no longer fresh.
  440.  
  441. =back
  442.  
  443. =head1 SEE ALSO
  444.  
  445. L<HTTP::Headers>, L<HTTP::Message>, L<HTTP::Status>, L<HTTP::Request>
  446.  
  447. =head1 COPYRIGHT
  448.  
  449. Copyright 1995-2004 Gisle Aas.
  450.  
  451. This library is free software; you can redistribute it and/or
  452. modify it under the same terms as Perl itself.
  453.  
  454.